Проблема с таблицей InventDim

[Anton Sk.]

Существует неотфактурованная Закупка со строками. В строках нет ГТД. Хочу по нажатию на кнопку во все строки Закупки вставить один и тот же ГТД (новый или уже существующий, выбираю/ввожу в дилоге).
Нахожу строчку в InventDim. Изменяю поле InventGTDId_Ru. При этом изменяю таблицу InventGTD_Ru, если там нет пары: ItemId - inventGTD_Ru. Все это в цикле для всех строк Закупки.
Так вот, поле InventGTDId_Ru в существующей строке таблицы InventDim не редактируется. С Закупкой еще ничего не делалось. Пытаюсь в браузере Аксапты внести изменения в это поле. То же самое.


Но в форме PurchTable в строках вручную мы можем поправиь ГТД. А вот в коде не получается. В чем дело?

P.S. Предполагается, что товар, который приходуется в данной Закупке, должен иметь ГТД.

[SergS]

Таблица InventDim славится тем что в нее нельзя добавлять и редактированть записи из формы InventDim

//Это перекрытый метод update() у таблицы InventDim Insert такой же

void update(boolean doUpdate = false)
{
if (doUpdate)
super();
}

Соответственно если необходимо добавить/Изменить данные в этой таблице в методы Insert и Update необходимо передавать параметр

InventDim.Update(true);
inventDim.Insert(True);

[Wamr]

Использование InventDim.Update(true); inventDim.Insert(True); в данном случаи мне кажется неправильным, так как новая аналитика может уже существовать
Лучше поступить так

PHP код:

InventDim  oldInventDim, newInventDim;
;

// Для каждой строки закупки получаем
oldInventDim = InventDim::find(purchLine.InventDimId);

// Изменяем ГТД
oldInventDim.InventGtdId_RU = "ГТД"

// создаем или находим аналитику
newInventDim = InventDim::findOrCreate(oldInventDim);

// изменяем строку закупки
purchLine.InventDimId = newInventDim.InventDimId
purchLine.update(); 


Еще интересно посмотреть, что будет со складскими проводками и остатками по старой и новой аналитикам

[ДК]

Проблема развивается следующим образом:
Простая установка пустых ГТД не дает нужного результата т.к. в проводках будут участвовать СТАРЫЕ значения ГТД!

[mazzy]

Цитата:

Изначально опубликовано ДК
...в проводках будут участвовать СТАРЫЕ значения ГТД!

в РАЗНЕСЕННЫХ проводках (отфактурованных заказов)? конечно. А как иначе?

Для изменения аналитики в разнесенных складских проводках пользуйтесь формой Редактирование кодов аналитики в функциях номенклатуры.

[EVGL]

Цитата:

в РАЗНЕСЕННЫХ проводках (отфактурованных заказов)?

В ЛЮБЫХ. Никогда не замечали: стираете аналитику в строке заказа, а в складской проводке значение остается? Известная feature.

Теперь по сути: Wamr все правильно написал. А метод purchLine.update() (точнее, вызываемый им PurchLineType.update()) сам займется тем, чтобы обновлять связанные складские проводки, остатки и резервирование.

[ДК]

PHP код:

void clicked()
{
    SalesLine           salesLineSelect;
    InventTrans         inventTrans;
    InventDim           oldInventDim, newInventDim;
    ;
        TTSBEGIN;
        while select forupdate salesLineSelect where salesLineSelect.SalesId == SalesTable.SalesId
        {
            //получили аналитику строки
            oldInventDim = InventDim::find(salesLineSelect.inventDimId);
            //установили "пустую" ГТД
            oldInventDim.InventGtdId_RU = "";
            //нашли / создали новую аналитику
            newInventDim = InventDim::findOrCreate(oldInventDim);
            //если есть проводки - правим InventDim в проводке
            inventTrans = InventTrans::findTransId(salesLineSelect.InventTransId, true);
            if (inventTrans)
            {
                inventTrans.inventDimId = newInventDim.InventDimId;
                inventTrans.doUpdate();
            }
            //а вот теперь меняем аналитику в строке на новую
            salesLineSelect.InventDimId = newInventDim.InventDimId;
            salesLineSelect.update();
        }
        TTSCOMMIT;
        Salesline_ds.research();
} 


А стандартные методы, работающие для других аналитик, не всегда работают так же с ГТД. feature наверное

[EVGL]

Сотрите свой код, лучше не позорьтесь.

[ДК]

Цитата:

Изначально опубликовано EVGL
Сотрите свой код, лучше не позорьтесь.

Ну, в Axapta я еще совсем "зеленый", а этот код (для моего случая) работает.
Аргументы можно?

[EVGL]

Прошу прощения, злой я сегодня.
Аргументы:

1. inventTrans.doUpdate() - это очень сильно. Опустив вызов .update(), вы отключили десятки экранов кода, который обновляет накопленные суммы складских остатков, уменьшая остатки по старому коду аналитики и увеличивая по новому. База данных испорчена до следующего запуска корректировки данных складского модуля.
2. по существу задачи. Сам тот эффект, с которым вы боретесь, запрограммирован датчанами нарочно в методе InventDim.mergeUsedDim(). На тот счет существует запрос в NSS, в ответе на который объясняется, что сброс аналитики ведет к несоответствиям в данных о резервированию. Лично подтвердить не могу, но им виднее.
3. среди тех проводок, что вы огребли методом InventTrans::findTransId(), могут быть и разнесенные.
4. метод InventTrans::findTransId() возвращает только одну запись, хотя отношение строк заказа к складким проводкам - 1:N.
5. Более того, складские проводки не должны иметь ту же аналитику, что и строка заказа. Пример: заказ на 20 экскаваторов порождает отгрузку 20 единиц с различными серийными номерами. 1 строка заказа -> 20 проводок с различной аналитикой.

Уффф...

[ДК]

Спасибо огромное за столь аргументированый ответ.
Мой случай:
1. Учет по ГТД не ведется. Т.е. мне нужно сначала установить ГТД, Вывести СФ (без обработки) и сбросить (обнулить) ГТД.
2. Доступность кнопок Установка/Сброс определяется состоянием Заказа, т.е. разнесенных существуют только проводки со статусом "В заказе".
3. Серийных номерв/партий нет, т.е. SalesLine - InventTrans 1:1
Т.е. для моего случая код абсолютно рабочий, кроме того, почему

Цитата:

Опустив вызов .update(),

? Наоборот, разобравшись с этим методом мы его и запускаем.
Да мы натолкнулись на метод InventDim.mergeUsedDim(), который не совсем правильно отрабатывает именно ГТД.
В любом случае - спасибо.

[EVGL]

Можно ли называть рабочим, скажем, сгнивший деревенский мост, посредине которого здоровенная дыра? По вашей логике, можно, поскольку мотоциклы, которыми в 80% пользуются местные, могут ее объехать, а вокруг дыры построены перила.

Еще раз: вместо InventTrans.doUpdate() ставят InventTrans.update().

SalesLine - InventTrans 1:1 нарушится сразу, как только кто-нибудь сдалает частичную отгрузку.

И вообще: правильно ли я понял, что проблема в выводе на печать счета-фактуры? Почему же ее решение в том, чтобы раскурочивать заказы?

[ДК]

PHP код:

....
            //если есть проводки - правим InventDim в проводке
            while select forupdate inventTrans where inventTrans.InventTransId == salesLineSelect.InventTransId
            {
              if (inventTrans)
                {
                    inventTrans.inventDimId = newInventDim.InventDimId;
                    inventTrans.Update();
                }
            }
            //а вот теперь меняем аналитику в строке на новую
.... 


Хозяин, а такой колор подойдет? © Мимино
Так.. в результате вроде родили деревенский мост без дырки.
Спасибо.

[EVGL]

Почти... почти...
Вот пример запроса из InventUpd_Financial.updateFinancialReceipt(), отсекающего недопустимые статусы:

PHP код:

while select forupdate inventTrans
        Index hint TransIdIdx
        where inventTrans.inventTransId     == movement.transId()         &&
              inventTrans.statusIssue       == StatusIssue::None          &&
              inventTrans.statusReceipt     == StatusReceipt::Received
{ 


Ваш запрос берет лишнее в случае частичной отгрузки/резервирования/регистрации и т.п.

И последняя [уже придирка] к несчастным 4 строчкам кода: if (inventTrans) лишено смысла, т.к. внутрь цикла while select можно войти только тогда, если запрос успешно вернул очередную проводку. if будет выполняться всегда.

[ArturK]

Я пишу в точности как вы предложили

PHP код:

   salesLineSelect.InventDimId = newInventDim.InventDimId;
            salesLineSelect.update(); 


Но у меня никакого обновления в строке не происходит.
То что новый newInventDim.InventDimId есть - это точно, проверяю info().
В чем может быть причина?

Правда вместо конструкции

PHP код:

 select forupdate ... 


я использую, перебор Query c помощью getNext()
Это может влиять на неработу update()?