Как узнать у каких групп есть права на MenuItem ?

[egorych]

Собственно нужно по конкретному MenuItem узнать, у каких групп есть права на него? Как это можно сделать?

[belugin]

static void Test_AccessibleForWho(Args _args)
{
    SecurityKeySet secSet;
    UserGroupInfo userGroup;
    DomainInfo domain;
    str items;
    container menuItems = [
        [menuItemDisplayStr(UKS_IV_Load), AccessRecordType::MenuItemDisplay]
    ];
    str accessibleMenuItems()
    {
        int i;
        MenuItemName name;
        AccessRecordType type;
        str ret;
    ;
        for (i=1; i<=conLen(menuItems); i++)
        {
            [name, type] = conPeek(menuItems, i);
            if (secSet.menuItemAccess(name,  type))
            {
                if (ret)
                    ret += ', ';
                ret += SysDictMenu::newMenuItem(name,
                    (type == AccessRecordType::MenuItemAction) ?
                        MenuItemType::Action : MenuItemType::Display
                ).label()+strFmt(', %1', secSet.menuItemAccess(name,  type));
            }
        }
        return ret;
    }
;
    while select userGroup
    {
        while select domain
        {
            secSet  = SysSecurity::constructSecurityKeySet();
            secSet.loadGroupRights(userGroup.id, domain.Id);
            items = accessibleMenuItems();
            if (items)
            {
                info(strFmt('%1;%2: %3',  userGroup.id, domain.Id, items));
            }
        }
    }
}

[belugin]

До кучи еще SC

static void Test_AccessibleSCForWho(Args _args)
{
    SecurityKeySet secSet;
    UserGroupInfo userGroup;
    DomainInfo domain;
    str items;
;
    while select userGroup
    {
        while select domain
        {
            secSet  = SysSecurity::constructSecurityKeySet();
            secSet.loadGroupRights(userGroup.id, domain.Id);

            if (secSet.access(securityKeyNum(Admin)) >= AccessType::View)
            {
                info(strFmt('%1;%2: %3',  userGroup.id, domain.Id, items));
            }
        }
    }
}

[Gustav]

Цитата:

Сообщение от belugin

    while select userGroup
    {
        while select domain
        {
            secSet  = SysSecurity::constructSecurityKeySet();
            secSet.loadGroupRights(userGroup.id, domain.Id);
            items = accessibleMenuItems();
            if (items)
            {
                info(strFmt('%1;%2: %3',  userGroup.id, domain.Id, items));
            }
        }
    }
}

Хорошо. Только я бы еще домены проверил. У меня их, например, нет. Т.е. как-то так наскоряк модифицировать:

    while select userGroup
    {
        if ((select count(RecId) from DomainInfo).RecId)
        {
            while select domain
            {
                secSet  = SysSecurity::constructSecurityKeySet();
                secSet.loadGroupRights(userGroup.id, domain.Id);
                items = accessibleMenuItems();
                if (items)
                {
                    info(strFmt('%1;%2: %3',  userGroup.id, domain.Id, items));
                }
            }
        }
        else // NO DOMAINS
        {
            secSet  = SysSecurity::constructSecurityKeySet();
            secSet.loadGroupRights(userGroup.id, '');
            items = accessibleMenuItems();
            if (items)
            {
                info(strFmt('%1;%2: %3',  userGroup.id, domain.Id, items));
            }
        }
    }

[egorych]

Благодарствую премного!

[belugin]

Ага. Вообще в тулзу надо бы оформить...

[egorych]

Получается, что это работает, если на MenuItem навешен SecurityKey ?
А если он пустой, то показывает, что доступно всем - хотя в меню у всех выключено

[belugin]

Каким образом выключено в меню?

[egorych]

Права групп пользователей - в выпадающем списке выбираем "Главное меню", ищем нужный пункт и жмем "нет доступа". или закрываем какую-то ветку, например "отчеты" - закрываются и все что ниже в меню

[sukhanchik]

2egorych:
не... для MenuItem см здесь

а для SecurityKey (независимо от MenuItem) см здесь

[egorych]

2sukhanchik - я так и пробовал - 1 вариант показывает правильно если есть SK - если не привязан ни к какому ключу - показывает доступ для всех групп.

[belugin]

А в случае такого запрещения можно вызвать этот MenuItem из другого меню или по кнопке?

[sukhanchik]

2belugin: Думаю, что нет - т.к. в этом случае (когда MenuItem без SK) в AccessRightList должна появиться запись о конкретном MenuItem - а значит на него не должен быть доступ

[egorych]

Правильно - item выключается во всех менюшках, куда был вставлен.