В очередной раз о ошибках синхронизации

[greench]

Доброго времени суток. При попытке синхронизации чере Администрирование\Периодические операции выдает ошибку:

Невозможно выполнить команду языка определения данных в ().
База данных SQL обнаружила ошибку.

Таких строк много. В итоге выдает строку:

Невозможно выполнить команду языка определения данных в ().
База данных SQL обнаружила ошибку.

Каким образом получить более информативные сообщения: в каких таблицах, почему?

И вообще как с этим бороться? переиндексирование не помогло.

P.S. AX 4.0. SP 2

[belugin]

А в EventLog что?

[greench]

Цитата:

Сообщение от belugin

А в EventLog что?

Вот это мне и нужно было, не знал просто где смотреть. Думал такие ошибки аксапта пишет в какие-то свои логи.

Спасибо.

[DSPIC]

Вот простенький джобец, который позволяет локализовать проблемную таблицу.

//DSPIC
static void synchronizationCheck(Args _args)
{
    Dictionary              dictionary = new Dictionary();
    TableId                 tableId;
    RunbaseProgress         runbaseProgress = new RunbaseProgress();
    ;


    tableId = dictionary.tableNext(tableId);

    runbaseProgress.setTotal(dictionary.tableCnt());
    runbaseProgress.setCaption("SynchronizationCheck");

    while (tableId)
    {
        appl.dbSynchronize(tableId, false, true, false);

        runbaseProgress.setText(tableId2Name(tableId));

        info (strfmt("Table '%1' - OK", tableId2Name(tableId)));

        runbaseProgress.incCount();

        tableId = dictionary.tableNext(tableId);
    }
}

[sukhanchik]

Поставьте в настройках АОСа на закладке Tracing галку Allow client tracing on Application Object Server instance. И будет Аксапта все вам писать в инфолог сразу. Только после установки галки нужен будет рестарт АОСа и как следствие - повторный запуск синхронизации

[Bishop]

Цитата:

Сообщение от DSPIC

Вот простенький джобец, который позволяет локализовать проблемную таблицу.

По-моему, некорректный джобец. Во-первых, он работает до первой ошибки, во-вторых, имя таблицы с ошибкой как раз не выводится, а в инфологе только куча строк "Table xxx - ОК".

Вчера как раз тоже написал подобный джоб, может кому пригодится:

// Синхронизация с выводом наименований "неправильных" таблиц
static void DbSynchronize(Args _args)
{
    #AviFiles
    Dictionary              dictionary;
    DictTable               dictTable;
    int                     i;
    SysOperationProgress    progress;
    ;
    dictionary = new Dictionary();
    progress = SysOperationProgress::newGeneral(#AviUpdate, "Синхронизация", dictionary.tableCnt());
    for (i = 1; i <= dictionary.tableCnt(); i++)
    {
        dictTable = new DictTable(dictionary.tableCnt2Id(i));
        if  (dictTable.isSql() &&
                (
                    !dictTable.configurationKeyId()    ||
                    isConfigurationkeyEnabled(dictTable.configurationKeyId())
                )
            )
        {
            try
            {
                progress.setText(dictTable.name());
                progress.setCount(i);
                if (!appl.dbSynchronize(dictTable.id(), false, true, false))
                {
                    warning(strfmt("Проблемы с таблицей %1 (Id = %2)!", dictTable.name(), dictTable.id()));
                }
            }
            catch (Exception::Error)
            {
                warning(strfmt("Проблемы с таблицей %1 (Id = %2)!", dictTable.name(), dictTable.id()));
            }
        }
    }
    info("Синхронизация завершена");
}

По опыту, проблемы при синхронизации возникают в основном в двух случаях:
- некорректные данные в таблице SqlDictionary (чаще всего - их отсутствие),
- нарушение уникального индекса (самая "попса" - табличка InventDim при отключении складской аналитики)

[DSPIC]

Цитата:

По-моему, некорректный джобец. Во-первых, он работает до первой ошибки, во-вторых, имя таблицы с ошибкой как раз не выводится, а в инфологе только куча строк "Table xxx - ОК".

Не то чтобы некорректный, просто красивости делать не предполагалось. Просто запустил, он вывалился на ошибке, посмотрел в инфологе последнюю удачно засинхронизированную таблицу, нашел в АОТ следующую-проблемную. + помнится, когда я этот джоб писал, у меня не отрабатывал catch при ошибке синхронизации - я уж не стал разбираться почему - и так понятно где проблема. А у вас он отрабатывает?!

Цитата:

Вчера как раз тоже написал подобный джоб...

[Bishop]

Цитата:

Сообщение от DSPIC

Просто запустил, он вывалился на ошибке, посмотрел в инфологе последнюю удачно засинхронизированную таблицу, нашел в АОТ следующую-проблемную.

Интересно - как это? Синхронизация не в алфавитном порядке же идет...

Цитата:

Сообщение от DSPIC

+ помнится, когда я этот джоб писал, у меня не отрабатывал catch при ошибке синхронизации - я уж не стал разбираться почему - и так понятно где проблема. А у вас он отрабатывает?!

Отрабатывает , но возможно что не во всех случаях. Вчера была проблема с отсутствием данных в SqlDictionary - там выкидывается Exception::Error (соответственно, ловится).

[DSPIC]

Цитата:

Интересно - как это? Синхронизация не в алфавитном порядке же идет...

А, да - каюсь. Собственно проблема решается элементарно - строку с info(...) поставить сразу после while, непосредственно перед синхронизацией и текст "OK" поменять на "Processing" (Наверное это не последний релиз джоба)
В общем пример будем считать лабораторным - как найти проблему синхронизации програмно - понятно. Спасибо за бдительность и уточнение.