Query и Map

[olesh]

А возможно ли использовать Map в Query? Что-то с ходу не получилось...

Можно ли такой код переписать, используя Query/QueryRun?

    CustVendTrans custVendTrans;
    VendTrans vendTrans;
;
    custVendTrans = vendTrans;

    while select AccountNum, sum(AmountMST) from custVendTrans
        group by AccountNum
    {
        print custVendTrans.AccountNum;
    }

[EVGL]

Query же и так динамический. Если нужно извратиться, сформируйте его интеллигентно, с использованием MappingsInfo_RU.

[alicedr]

А подробнее?
Столкнулась с такой ситуацией: Есть мап, и есть запрос с группировкой.

//запись информации в таблицу логов
void InsertLog(FactureJour_RU    _fJour,
               FactureTransLines _fTrans, //map сопоставляющий FactureTrans_RU
                                         //и аналогичную таблицу, где поля называются по-другому
               str               _calledFrom)
{
   FactureTransLines  factureTransLines=(_ftrans);
   ;

   this.FactureId           = _fJour.FactureId;
   this.RefTableId          = _ftrans.TableId;
// так  работает
   if (this.RefTableId == tableNum(FactureLines))
   {
    this.ZEU_LineAmountMST = (select firstonly  sum(ZEU_LineAmountMST)
                              from factureLines
                              where factureLines.ZEU_FactureId == _fjour.FactureId
                                 &&  factureLines.ZEU_Module   == _fjour.Module).ZEU_LineAmountMST;
   }
   else
   {
    this.ZEU_LineAmountMST = (select firstonly  sum(LineAmountMST)
                              from factureTrans_RU
                              where factureTrans_RU.FactureId == _fjour.FactureId
                                 &&  factureTrans_RU.Module   == _fjour.Module).LineAmountMST;
   }
//А так не работает. Ошибки нет, но запрос выдает нули
/*    this.ZEU_LineAmountMST = (select firstonly  sum(LineAmountMST)
                              from factureTransLines
                              where factureTransLines.FactureId == _fjour.FactureId
                                 &&  factureTransLines.Module   == _fjour.Module).LineAmountMST;
*/
   this.CalledFrom       = _calledFrom;

   this.insert();
}

Почему запрос на мапе работает неправильно?

И сопутствующий вопрос: Как правильно из запроса получить сразу 3 переменные, как-нибудь так (т.е. не выполняя запрос для каждой переменной):

[s1,s2,s3] = (select firstonly  sum( s1 ), sum( s2 ), sum( s3 )
                              from factureLines
                              where factureLines.ZEU_FactureId == _fjour.FactureId);

[AndyD]

Просто, таким образом селект не использует табличную переменную, определенную вами

Надо делать так

//запись информации в таблицу логов
void InsertLog(FactureJour_RU    _fJour,
               FactureTransLines _fTrans, //map сопоставляющий FactureTrans_RU
                                         //и аналогичную таблицу, где поля называются по-другому
               str               _calledFrom)
{
   FactureTransLines  factureTransLines=(_ftrans);
   ;

   this.FactureId           = _fJour.FactureId;
   this.RefTableId          = _ftrans.TableId;
   select firstonly  sum(LineAmountMST)
   from factureTransLines
   where factureTransLines.FactureId == _fjour.FactureId
       &&  factureTransLines.Module   == _fjour.Module;
   this.ZEU_LineAmountMST = factureTransLines.LineAmountMST;

   this.CalledFrom       = _calledFrom;

   this.insert();
}

Цитата:

И сопутствующий вопрос: Как правильно из запроса получить сразу 3 переменные, как-нибудь так (т.е. не выполняя запрос для каждой переменной)

select sum( s1 ), sum( s2 ), sum( s3 )
from factureLines
where factureLines.ZEU_FactureId == _fjour.FactureId;
s1 = factureLines.s1;
s2 = factureLines.s2;
s3 = factureLines.s3;

[ice]

а firstonly вместе с sum() точно правильно?

[AndyD]

Цитата:

Сообщение от ice

а firstonly вместе с sum() точно правильно?

копипаст
не нужен он там, конечно

[alicedr]

Согласна, firstonly там действительно не нужен

Усложняем задачу.

    //qbds = query.addDataSource(tablenum(FactureTrans_RU));
    qbds = query.addDataSource(tablenum(FactureTransLines)); //заменили на мап
    qbds.orderMode(OrderMode::GroupBy);

    qbds.addSelectionField(fieldnum(FactureTransLines, LineAmountMST), SelectionField::Sum);
    qbds.addRange(fieldnum(FactureTransLines, FactureId)).value(_factureJour.FactureId);
    qbds.addRange(fieldnum(FactureTransLines, Module)).value(SysQuery::value(_factureJour.Module));
 // и другие addRange
    qr = new QueryRun(query);
    while(qr.next())
    {
        factureTrans = qr.get(tablenum(FactureTransLines));
      //разные действия
   }

В цикл while не заходит, т.е. записей запрос не выдает.
Аналогичная конструкция с просто таблицей, а не мапом, работает.

[lev]

Цитата:

Сообщение от alicedr

Согласна, firstonly там действительно не нужен

Усложняем задачу.

    //qbds = query.addDataSource(tablenum(FactureTrans_RU));
    qbds = query.addDataSource(tablenum(FactureTransLines)); //заменили на мап
    qbds.orderMode(OrderMode::GroupBy);

    qbds.addSelectionField(fieldnum(FactureTransLines, LineAmountMST), SelectionField::Sum);
    qbds.addRange(fieldnum(FactureTransLines, FactureId)).value(_factureJour.FactureId);
    qbds.addRange(fieldnum(FactureTransLines, Module)).value(SysQuery::value(_factureJour.Module));
 // и другие addRange
    qr = new QueryRun(query);
    while(qr.next())
    {
        factureTrans = qr.get(tablenum(FactureTransLines));
      //разные действия
   }

В цикл while не заходит, т.е. записей запрос не выдает.
Аналогичная конструкция с просто таблицей, а не мапом, работает.

а какой запрос покажет:

info(qbds.toString());

?

[Slava Chernenko]

И какую из двух замапленных таблиц вы ожидаете квери должен кверить?

[SRF]

Мап не содержит данных, данные хранятся в таблицах. Поэтому запросы работают корректно, возвращают пусто.

Если вы хотите сделать с помощью query, то воспользуйтесь советом EVGL - использование объекта MappingsInfo_RU.

Посмотрите использование в стандарте метода MappingsInfo_RU::createMapWithFieldId.

В вашем случае будет примерно так :

Map  map = MappingsInfo_RU::createMapWithFieldId(_fTrans.TableId,tablenum(FactureTransLines));
;
...
qbds.query.addDataSource(_fTrans.tableId);
if (map.exists(fieldIdpname(FactureTransLines, FactureId)))
{
  qbds.addRange(map.lookup(fieldIdpname(FactureTransLines, FactureId))).value(_factureJour.FactureId)
}
...