AX2012 R3 Тормозит формирование РН

[Brave]

Добрый день! AX2012 R3
Формирование расходных накладных происходит медленно, при трассировке и выявлении проблемы, выяснился неприятный момент, а именнно:
В методе setEstimate:

/**
    Returns true if the estimated amount is calculated and has changed
**/
server boolean setEstimate(SalesTotals _salesTotals = null)
{
    SalesTotals             salesTotals;
    SalesUpdate             qtySpec;
    CustParameters          custParameters          = CustParameters::find();
    TypeOfCreditmaxCheck    typeOfCreditmaxCheck    = custParameters.CreditMaxCheck;
    boolean                 hasEstimatedChanged;
    AmountMST               estimatedOld;
    MCRSalesOrderTotals      mcrSalesOrderTotals;

    hasEstimatedChanged = false;
    //Total estimate for the order would be calculated on order save, if credit limit check is enabled for the company.
    if (this.custTable_CustAccount().shouldEstimateBeCalculated())
    {
        qtySpec = (typeOfCreditmaxCheck == TypeOfCreditmaxCheck::BalanceDelivered ? SalesUpdate::PackingSlip :
                   typeOfCreditmaxCheck == TypeOfCreditmaxCheck::BalanceAll       ? SalesUpdate::All         : 0);

        if (qtySpec && this.isCreditCheckEligible())
        {
            estimatedOld        = this.Estimate;

            if (this.mcrIsCallCenter())
            {
                if (qtySpec == SalesUpdate::All)
                {
                    mcrSalesOrderTotals = new MCRSalesOrderTotals(this);
                    this.Estimate = Currency::amountCur2MST(mcrSalesOrderTotals.getRemainingOrder(), this.CurrencyCode);
                }
                else
                {
                    salesTotals         = SalesTotals::construct(this, qtySpec);
                    this.Estimate       = Currency::amountCur2MST(salesTotals.totalAmount(), this.CurrencyCode);
                }
            }
            else
            {
                salesTotals         = (_salesTotals == null) ? SalesTotals::construct(this, qtySpec) : _salesTotals;
                this.Estimate       = Currency::amountCur2MST(salesTotals.totalAmount(), this.CurrencyCode, this.fixedExchRate());
            }

            hasEstimatedChanged = (this.Estimate != estimatedOld);
        }
    }

    this.Touched = NoYes::No;

    return hasEstimatedChanged;
}

Таблицы SalesTable, согласно настройкам используется класс:
MCRSalesOrderTotals
Внутри класса MCRSalesOrderTotals вызывается метод calcInvoicedExistMultiple
с жутким запросом приводящем к тормозам в базе (время выполнения 10-15 секунд, используется tempdb для операции HashMatch в плане):

select sum(EndDisc), sum(InvoiceAmount), sum(SalesBalance), sum(SumMarkup), sum(SumTax) from custInvoiceJour
        where custInvoiceJour.RefNum == RefNum::SalesOrder
        notexists join custInvoiceSalesLink
            where custInvoiceJour.SalesId          == custInvoiceSalesLink.SalesId
               && custInvoiceJour.InvoiceDate      == custInvoiceSalesLink.InvoiceDate
               && custInvoiceJour.InvoiceId        == custInvoiceSalesLink.InvoiceId
               && custInvoiceSalesLink.OrigSalesId != _salesTable.SalesId;

Сталкивался ли кто нибудь с подобными проблемами?
Обойти сей неприятный момент возможно, отключив "центр обработки вызовов"(метод mcrIsCallCenter()) но всё-таки может есть решения без выпиливания функционала?

[SRF]

Что то в запросе явно не хватает условия либо custInvoiceJour.SalesId = _salesTable.SalesId, либо custInvoiceSalesLink.SalesId = _salesTable.salesId.

Метод как я понимаю считает итоги по накладным с несколькими заказами, куда входит наш заказ, а не вообще по всем накладным с несколькими заказами, зачем все то считать ? См. метод calcInvoiced откуда он вызывается.

А в целом, если вы функционал не используете, отключите конф ключ и будет счастье, MS вроде как рекомендует включать только то, что используете)

[sukhanchik]

Цитата:

Сообщение от SRF

Что то в запросе явно не хватает условия либо custInvoiceJour.SalesId = _salesTable.SalesId, либо custInvoiceSalesLink.SalesId = _salesTable.salesId.

Условие добавлять как раз-таки не надо - оно не совсем корректное для случая накладных по нескольким заказам. А вот вопрос что хотим получить - это действительно вопрос. Судя по коду - хотим получить сумму всех накладных, в которых хоть как-то засветился наш заказ.
Тормоза придает условие custInvoiceSalesLink.OrigSalesId != _salesTable.SalesId;
Нужно неравенство пытаться превращать в равенство

[Raven Melancholic]

Я, может быть, как-то не понял логику работы, но получается, что тут мы суммируем вообще все накладные, разноска которых была запущена не из текущего заказа, ну и далее, тоже делаем с накладными расходами.
Ведь единственное ограничение на выборку это:

custInvoiceSalesLink.OrigSalesId != _salesTable.SalesId

но таких накладных, я думаю, не так уж и мало.

[SRF]

А чего это условие то не корректное ? Жаль что полностью код, не вставили из метода с комментарием, а выглядит он вот так :

    // There is at least one summary invoice so need to process each invoice separately.
    // [B]Select all non-summmary invoices[/B].  If no other record exists in CustInvoiceSalesLink
    // with a different origSalesId then there is only one sales order on the invoice and
    // therefore it is a non-summary invoice.
    select sum(EndDisc), sum(InvoiceAmount), sum(SalesBalance), sum(SumMarkup), sum(SumTax) from custInvoiceJour
        where custInvoiceJour.RefNum == RefNum::SalesOrder
        notexists join custInvoiceSalesLink
            where custInvoiceJour.SalesId          == custInvoiceSalesLink.SalesId
               && custInvoiceJour.InvoiceDate      == custInvoiceSalesLink.InvoiceDate
               && custInvoiceJour.InvoiceId        == custInvoiceSalesLink.InvoiceId
               && custInvoiceSalesLink.OrigSalesId != _salesTable.SalesId;

Т.е. этот запрос должен считать сумму по всем накладным текущего заказа, в которых нет других заказов - т.е. одиночные накладные.
Поэтому как мне кажется надо в три запроса добавить условие custInvoiceJour.SalesId = _salesTable.SalesId, которые содержат notexists join в этом методе.
Насчет равенства это да, но навскидку пока, быстро не придумал, как выбрать такие накладные без not exists join,
Сам метод считает сумму которая в накладных из данного заказа и считает ее так = сумма всех накладных только по этому заказу + доля из накладных где наш заказ включен как один из нескольких.

А вообще если не используете ключ отключите его, проблемы уйдут не только в этом методе.

[sukhanchik]

Цитата:

Сообщение от SRF

А чего это условие то не корректное ?
Т.е. этот запрос должен считать сумму по всем накладным текущего заказа, в которых нет других заказов - т.е. одиночные накладные.

А... прошу прощения... Ступил. Да, тогда все логично.

[Brave]

Добавили условие custInvoiceJour.SalesId = _salesTable.SalesId, всё залетало! Спасибо за совет и поддержку!

[trud]

Цитата:

Сообщение от Brave

Добавили условие custInvoiceJour.SalesId = _salesTable.SalesId, всё залетало!

А это случайно все не сломает, если у нас одна накладная будет включать несколько заказов? В этом случае условие будет не совсем правильное