Расширенные возможности Query - арифметические операции в условие Where.

[Lemming]

Добрый день, уважаемые коллеги!

Существует ли возможность с помощью Query создать запрос, который в SQL выглядит так:

select * from ExtendedTestData where Amount + Amount1 - Amount2 <> 0;

Следующее выражение

exQueryString = strfmt("(( %1 + %2 - %3 <> 0 ))",
                           fieldId2name(TableNum(ExtendedTestData), fieldNum(ExtendedTestData, Amount)),
                           fieldId2name(TableNum(ExtendedTestData), fieldNum(ExtendedTestData, Amount1)),
                           fieldId2name(TableNum(ExtendedTestData), fieldNum(ExtendedTestData, Amount2)));

приводит к ошибке: Ошибка расширенного диапазона запроса: Синтаксическая ошибка рядом с 34.


А, например, вот такое выражение

exQueryString = strfmt("(( %1 + %2 - %3 > 0 ))", ...

Генерирует следующий SQL код

SELECT A.KEY_,A.AMOUNT,A.AMOUNT1,A.AMOUNT2,A.RECID
FROM EXTENDEDTESTDATA A
WHERE ((DATAAREAID=?)
AND (((AMOUNT+AMOUNT1)-AMOUNT2)>1=?))
ORDER BY A.DATAAREAID,A.RECID OPTION(FAST 1)

с ошибкой : [Microsoft][ODBC SQL Server Driver][SQL Server]Line 1: Incorrect syntax near '='.


Со ссылкой http://www.axaptapedia.com/Expressions_in_query_ranges знаком.

Собственно, сам вопрос: умеет ли парсер кверей разбирать текст запроса, содержащий арифметические выражения?

[kashperuk]

А попробуй так:

strfmt("(( %1 + %2 > %3 ))", ...

А в первом варианте - <> не для АХ. В АХ это !=. Но такое тоже врядли работает.

[mazzy]

Цитата:

Сообщение от Lemming

Существует ли возможность с помощью Query создать запрос, который в SQL выглядит так:

Нет. Насколько я знаю ни арифметические операции, ни функции не допустимы в range.

[Russland]

Lemming, Так попробуйте:

    Query           query;
    ;

    query = new Query();
    query.addDataSource(tablenum(Table1));

    query.dataSourceTable(tablenum(Table1)).addRange(fieldNum(Table1, RecId)).value(

        //strfmt("(( (%1 + %2 - %3) <> 0 ))",
        strfmt("( (%1+%2*10) != (%3) ) )",
            fieldStr(Table1, Field2),
            fieldStr(Table1, Field4),
            fieldStr(Table1, Field5))
    );

    new DEV_QueryBrowser().run( query );

[Lemming]

Видимо не судьба...уже массу вариантов перепробовал, не хочет DAX хавать запросы такого плана. Ну ладно, буим знать.

[Russland]

Ну как не судьба?
Я же вам уже подсказал
Только перепишите под себя

Table1 заменяем на ExtendedTestData
Field2 - Amount
Field4 - Amount1
Field5 - Amount2

strfmt("( (%1+%2) != (%3) ) )", // умножение на 10 было для демонстрации того, что можно вставлять арифметические операции

Обратите внимание на то что открывающих скобок 3, а закрывающих 4!
Одну скобку кушает RecId

[glibs]

В Query вы не засунете больше, чем можно засунуть в Аксаптовский select. Я так думаю.

[dn]

Цитата:

Сообщение от Lemming

Видимо не судьба...уже массу вариантов перепробовал, не хочет DAX хавать запросы такого плана. Ну ладно, буим знать.

strfmt("(( %1 + %2 != %3 ))" - так в трешке точно работает (проверил на kr1)
strfmt("(( %1 + %2 - %3 != 0))" - а так ругается

[kashperuk]

Lemming, должно работать. Просто надо чтобы с обоих сторон были поля, насколько я знаю.

Толкьо что проверил - работает.
Так что показывайте весь код - будем ошибку искать

static void Job1(Args _args)
{
    Query q = new Query();
    QueryBuildDataSource qbds = q.addDataSource(tableNum(Table1));
    QueryBuildRange qbr = qbds.addRange(fieldNum(Table1, RecId));
    
    QueryRun    qr;
    Table1 table1;
    ;
    qbr.value(strFmt('((%1+%2) > (%3))', fieldStr(Table1, Field1), fieldStr(Table1, Field2), fieldStr(Table1, Field3)));
    
    qr = new QueryRun(q);
    while (qr.next())
    {
        table1 = qr.get(tableNum(Table1));
        info(strFmt("Field1 = %1, Field2 = %2, Field3 = %3, Field4 = %4", table1.Field1, table1.Field2, table1.Field3, table1.Field4));
    }
}

Вот данные из Table1:

Field1 Field2 Field3 Field4 dataAreaId recVersion RecId
100.00 100.00 100.00 100 tst 1 5637144576
50.00 100.00 30.00 120 tst 1 5637144577
20.00 20.00 80.00 -40 tst 458154613 5637144578

Данные из Infolog:
Info Message (12:27:00 pm) Field1 = 100.00, Field2 = 100.00, Field3 = 100.00, Field4 = 100
Info Message (12:27:00 pm) Field1 = 50.00, Field2 = 100.00, Field3 = 30.00, Field4 = 120

[Russland]

Цитата:

strfmt("(( %1 + %2 - %3 != 0))" - а так ругается

Цитата:

Просто надо чтобы с обоих сторон были поля

Правильно!
Но и ноль можно получть вычтя поле само из себя

        strfmt("( %1+%2*10-%3 != %3-%3 ) )",

[Lemming]

Цитата:

Сообщение от kashperuk

Lemming, должно работать. Просто надо чтобы с обоих сторон были поля, насколько я знаю.
...

Супер, спасибо!

Цитата:

Сообщение от Russland

Правильно!
Но и ноль можно получть вычтя поле само из себя

...

Браво!!! Вот оно! Всем спасибо! Заработало.