Получить значение поля по TableId, FieldId, RecId

[bodeaux]

Подскажите, пожалуйста, как получить значение поля таблицы, зная параметры TableId, FieldId, RecId.

[S.Kuskov]

Find для Common-а

[raz]

static void Job10(Args _args)
{
    TableId     tableId;
    RecId       recId;
    FieldId     fieldId;
    Common      common;
    ;
    common = new DictTable(tableId).makeRecord();
    
    select firstonly common
        where common.RecId == recId;
        
    info(strfmt("%1", common.(fieldId)));
}

[S.Kuskov]

Ещё вот так можно:

anyType find(TableId TableId, RecId RecId, FieldId FieldId)
    {
        Query Query;
        QueryBuildDataSource qbds;
        QueryRun QueryRun;
        Common Common;
        anyType ret;
        ;

        Query = new Query();
        qbds = Query.addDataSource(TableId);
        qbds.addRange(fieldName2id(TableId, 'RecId')).value(queryvalue(RecId));
        qbds.addSelectionField(FieldId, SelectionField::Database);
        qbds.firstOnly(true);

        QueryRun = new QueryRun(Query);
        if (QueryRun.next())
        {
            Common = QueryRun.get(TableId);
            ret = Common.(fieldId);
        }

        return ret;
    }

[userax2009]

Цитата:

Сообщение от raz

static void Job10(Args _args)
{
    TableId     tableId;
    RecId       recId;
    FieldId     fieldId;
    Common      common;
    ;
    common = new DictTable(tableId).makeRecord();
    
    select firstonly common
        where common.RecId == recId;
        
    info(strfmt("%1", common.(fieldId)));
}

Почему запуская Джоб, я получаю данную ошибку

[raz]

TableId     tableId = tableNum(Address);
FieldId     fieldId = fieldNum(Address, RecId);

Подправьте так.

[raz]

static void Job10(Args _args)
{
    TableId     tableId = tableNum(Address);
    FieldId     fieldId = fieldNum(Address, RecId);
    Common      common;
    ;
    common = new DictTable(tableId).makeRecord();
    
    select firstonly common;
        
    info(strfmt("%1", common.(fieldId)));
}

[userax2009]

Цитата:

Сообщение от raz

static void Job10(Args _args)
{
    TableId     tableId = tableNum(Address);
    FieldId     fieldId = fieldNum(Address, RecId);
    Common      common;
    ;
    common = new DictTable(tableId).makeRecord();
    
    select firstonly common;
        
    info(strfmt("%1", common.(fieldId)));
}

Мне надо более универсальный код, то есть я хочу узнать fieldId для любого поля любой таблицы. Возможно ли это ?

[S.Kuskov]

Перечисление полей таблицы